Tuesday, August 18, 2009 at 7:32 PM.

---

newsRiverSuite.podcatcher.downloadQueue

on downloadQueue (flOvernightDownload) {
	<<Changes
		<<7/19/07; 8:24:44 PM by DW
			<<Callbacks after downloading queue.
		<<1/19/06; 5:31:34 AM by DW
			<<Add parameter, flOvernightDownload, if true, we don't start a download after the stop time.
		<<1/18/06; 7:19:21 PM by DW
			<<Updated for newsRiver.root.
		<<9/19/05; 10:09:50 AM by DW
			<<If there's an error, record it and move to the next element. 
			<<Don't try to read items with errors.
			<<To clear the error to try again, delete the error sub-table.
		<<12/2/04; 7:30:21 AM by DW
			<<Created.
	local (adrdata = newsRiverSuite.init (), i, adrq);
	for i = sizeof (adrdata^.newsRiver.podcatcher.queue) downto 1 {
		adrq = @adrdata^.newsRiver.podcatcher.queue [i];
		try {
			if not defined (adrq^.error) {
				if flOvernightDownload {
					if date.hour () >= adrdata^.newsRiver.podcatcher.prefs.hourToStopDownloads {
						break}};
				newsRiverSuite.podcatcher.downloadEnclosure (adrq);
				adrdata^.newsRiver.podcatcher.downloads.[nameof (adrq^)] = adrq^;
				delete (adrq)}}
		else {
			new (tabletype, @adrq^.error);
			adrq^.error.message = tryerror;
			adrq^.error.when = clock.now ()}};
	if flOvernightDownload {
		if adrdata^.newsRiver.podcatcher.prefs.flOutlineEnclosures {
			newsRiverSuite.podcatcher.openLogOutline ()}};
	bundle { //callbacks, 7/19/07 by DW
		local (adrscript);
		for adrscript in @adrdata^.newsRiver.callbacks.afterDownloadQueue {
			try {
				adrscript^ ()}}}};
bundle { //test code
	downloadQueue (true)}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.