Tuesday, August 18, 2009 at 7:32 PM.

---

newsRiverSuite.podcatcher.logDownload

on logDownload (adrq) {
	<<Changes
		<<9/19/05; 10:18:24 AM by DW
			<<Strip markup from stuff we insert into the outline.
	on stripmarkup (s) {
		if typeof (s) == tabletype {
			table.assign (@s, xml.decompile (@s))};
		s = searchengine.stripmarkup (s);
		s = string.replaceall (s, "]]>", "");
		s = xml.entitydecode (s, flAlphaEntities:true);
		return (s)};
	local (adrdata = newsRiverSuite.init ());
	local (oldtarget = target.set (@adrdata^.newsRiver.podcatcher.log));
	op.firstsummit ();
	op.insert (clock.now (), up);
	op.insert (stripmarkup (adrq^.feedtitle), right);
	op.insert (stripmarkup (adrq^.description), right);
	bundle { //link to the podcast
		local (atts);
		new (tabletype, @atts);
		atts.type = "link";
		atts.url = html.getFileURL (adrq^.f);
		op.attributes.addgroup (@atts)};
	op.firstsummit ();
	target.set (oldtarget)}
<<bundle //test code
	<<logDownload (@iPodderData.queue.["01138"])

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.