Tuesday, August 18, 2009 at 7:36 PM.

---

photoFanSuite.getFeedInfo

on getFeedInfo (adrfeed) {
	<<Changes
		<<3/15/08; 8:06:50 PM by DW
			<<Use photoFanSuite.httpClient instead of tcp.httpreadurl.
		<<11/27/07; 11:36:30 AM by DW
			<<Add subfoldername element.
		<<11/6/07; 7:19:11 PM by DW
			<<Don't copy the xtstruct into the feed table. 
		<<4/20/07; 9:03:46 PM by DW
			<<Support OPML reading lists.
		<<4/14/07; 7:55:05 PM by DW
			<<Created.
	local (url = nameof (adrfeed^), xstruct, adr, nameitem);
	local (xmltext = photoFanSuite.httpClient (url)); //3/15/08 by DW
	xml.compile (xmltext, @xstruct);
	<<scratchpad.flickrxstruct = xstruct
	try {
		local (adrrss = xml.getaddress (@xstruct, "rss"));
		local (adrchannel = xml.getaddress (adrrss, "channel"));
		adrfeed^.title = xml.getvalue (adrchannel, "title");
		adrfeed^.link = xml.getvalue (adrchannel, "link");
		adrfeed^.description = xml.getvalue (adrchannel, "description");
		adrfeed^.type = "rss"}
	else {
		local (adropml = xml.getaddress (@xstruct, "opml"));
		local (adrhead = xml.getaddress (adropml, "head"));
		adrfeed^.title = xml.getvalue (adrhead, "title");
		adrfeed^.link = "";
		adrfeed^.description = "";
		adrfeed^.type = "opml"};
	photoFanSuite.initFeed (adrfeed)}
<<bundle //test code
	<<local (adrfeed)
	<<for adrfeed in @user.photoFan.feeds
		<<getfeedinfo (adrfeed)

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.